home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side B).zip / Softdisk Magazette Volume 1, No. 06 (1982-02)(Softdisk)(Side B).do / EMILS'.PDL.TABLET.bas < prev    next >
BASIC Source File  |  1996-12-24  |  2KB  |  46 lines
  1. 10  REM <CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J> AN EMIL PROGRAM <CTRL-J><CTRL-J><CTRL-J><CTRL-J><CTRL-J>
  2. 100  LOMEM: 16384
  3. 110 BU = 49249:KB = 49152
  4. 120 T1 = 1:X1 = 279/255:Y1 = 191/255:T = 49234
  5. 130  HOME : TEXT : HGR 
  6. 140  GOSUB 500:ZZ = 0
  7. 150  INPUT "WHAT BACKGROUND COLOR ";BC: HCOLOR= BC: HPLOT 0,0
  8. 160  CALL 62454
  9. 170  GOSUB 500
  10. 180  INPUT "COLOR ";CL: HCOLOR= CL
  11. 190  IF ZZ = 0  THEN ZZ = 1: GOTO 480
  12. 200  HOME : VTAB 24: PRINT "TO STOP TYPE =S="
  13. 210  PRINT "TYPE =T= TO TOGGLE SCREEN"
  14. 220 A =  PDL(1):B =  PDL(0)
  15. 230 X =  INT(A *X1): IF X >279 -P  THEN X = 279 -P
  16. 240 Y =  INT(B *Y1): IF Y >191 -P1  THEN Y = 191 -P1
  17. 250  IF  PEEK(KB) >127  THEN 330
  18. 260  IF  PEEK(BU) <128  THEN 290
  19. 270  FOR G = 0 TO P1: HPLOT X,Y +G TO X +P,Y +G: NEXT 
  20. 280  GOTO 220
  21. 290  HPLOT X,Y
  22. 300  HCOLOR= BC: HPLOT XO,YO:XO = X:YO = Y
  23. 310  HCOLOR= CL
  24. 320  GOTO 220
  25. 330  GET Z$: IF Z$ < >"S"  THEN 440
  26. 340  POKE T +1,0
  27. 350  PRINT "=A= CHANGE COLOR  =E= CHANGE PIXELL SIZE";: PRINT "=B= CHANGE PIC.": PRINT "=C= SAVE PIC."
  28. 360  PRINT "=D= EXIT PROGRAM ........ WHICH?";
  29. 370  GET Z$:Z =  ASC(Z$) -64: IF Z <1  OR Z >5  THEN 370
  30. 380 : HOME : VTAB 24
  31. 390  ON Z GOTO 170,140,410,400,480
  32. 400  END 
  33. 410  INPUT "PIC.NUMBER ";Z
  34. 420  PRINT : PRINT "<CTRL-D>BSAVE PIC."Z;",A$2000,L$2000"
  35. 430  GOTO 200
  36. 440  IF Z$ < >"T"  THEN 220
  37. 450  IF T1 = 1  THEN T1 = 0: GOTO 470
  38. 460 T1 = 1
  39. 470  POKE T +T1,0: GOTO 220
  40. 480  PRINT : INPUT "PIXELL SIZE (X BY Y)?";P,P1
  41. 490 P =  ABS(P -1):P1 =  ABS(P1 -1): GOTO 200
  42. 500  PRINT "           COLORS"
  43. 510  PRINT "=0=BLACK  =1=GREEN  =2=VIOLET  =3=WHITE"
  44. 520  PRINT "=4=BLACK  =5=RED    =6=BLUE    =7=WHITE"
  45. 530  RETURN 
  46. 600  REM <CTRL-J>5 FEB 1982 @<CTRL-J>